//===== rAthena Script ======================================= 
//= Renewal Archer Job Quest
//===== By: ================================================== 
//= Kisuka
//===== Current Version: ===================================== 
//= 1.1
//===== Compatible With: ===================================== 
//= rAthena Project
//===== Description: ========================================= 
//= Job Change to Archer Class
//===== Additional Comments: ================================= 
//= 1.0 First Version. [Kisuka]
//= 1.1 Added support for Baby classes. [Euphy]
//============================================================ 
payon_in02,64,71,4	script	Archer Guildsman#archer	85,{
	if (Upper == 1) {
		if (Class == Job_Novice_High && (ADVJOB == Job_Sniper || ADVJOB == Job_Clown || ADVJOB == Job_Gypsy)) {
			mes "[Archer Guildsman]";
			mes "Hey, I know you.";
			mes "You took this test";
			mes "before, didn't you?";
			next;
			mes "[Archer Guildsman]";
			mes "Ah, you must have been";
			mes "to Valhalla and been reborn.";
			mes "Wow, that's so impressive!";
			next;
			if (!callfunc("F_CanChangeJob")) {
				mes "[Archer Guildsman]";
				mes "Err...";
				mes "You'd better learn all the Basic Skills first before you can become an Archer.";
				next;
				mes "[Archer Guildsman]";
				mes "Alright, see you later.";
				close;
			}
			mes "[Archer Guildsman]";
			mes "Well then. I don't";
			mes "need to say anything else.";
			mes "I know you'll make a great Archer...";
			next;
			skill "NV_TRICKDEAD",0,SKILL_PERM;
			jobchange Job_Archer_high;
			skill "AC_MAKINGARROW",1,SKILL_PERM;
			skill "AC_CHARGEARROW",1,SKILL_PERM;
			mes "[Archer Guildsman]";
			mes "Although there's no special";
			mes "reward for you this time, I hope you understand. Take care of yourself.";
			close;
		}else{
			mes "[Archer Guildsman]";
			mes "Oh...?";
			mes "Hey, what are";
			mes "you doing here...?";
			next;
			mes "[Archer Guildsman]";
			mes "I can tell that you're not cut out to be an Archer. It sort of feels like you're meant to do";
			mes "something else...";
			close;
		}
	}
	mes "[Archer Guildsman]";
	mes "Nice to meet you. How may I help you?";
	next;
	switch(select("I want to be an Archer.:I need the requirements, please.:Nothing, thanks.")) {
	case 1:
		mes "[Archer Guildsman]";
		if(BaseJob != Job_Novice) {
			if(BaseJob == Job_Archer)
				mes "Haha, you are kidding me...";
			else {
				mes "I feel sorry but only Novices can change their job.";
				mes "You already have your own decent job, don't you?";
			}
			close;
		}else{
			mes "You are... "+strcharinfo(0)+", right?";
			next;
			if (!callfunc("F_CanChangeJob")) {
				mes "[Archer Guildsman]";
				mes "Well, you're not at the right skill level.";
				mes "Your job level must be at least ^4A4AFF10^000000 and your Basic Skill level should reach ^4A4AFFlevel 9";
				next;
				mes "[Archer Guildsman]";
				mes "Because an Archer needs extremely high concentration, so we do not accept those who have little patience.";
				close;
			}
			mes "[Archer Guildsman]";
			mes "Your Basic Skill is now enough..";
			mes "....Hm~~ so you are now ready to be an Archer. I will take the step right away.";
			next;
			mes "[Archer Guildsman]";
			mes "Congratulations! You are now an Archer! Also, we hope that you actively participate in many programs for the revival of the Archer Guild.";
			mes "Ah, items have arrived from the Production Department. Here, take these! These are all yours!";
			callfunc "Job_Change",Job_Archer;
			getitem 1742,1;	// N_Composite_Bow
			getitem 12004,1;	// Arrow_Container
			getitem 12009,1;	// Silver_Arrow_Container
			getitem 12008,1;	// Fire_Arrow_Container
			next;
			mes "[Archer Guildsman]";
			mes "Having a bow and arrows, now you became a real Archer.";
			mes "If you open the arrow container, there are arrows in it and then you can equip them.";
			mes "Well, I expect to hear better news from you. It's time to say goodbye.";
			mes "Bye.";
			close;
		}
	case 2:
		mes "[Archer Guildsman]";
		mes "An Archer has skills using a bow and has various talents.";
		mes "The greatest ability of an Archer is attacking enemies from a long distance.";
		next;
		mes "[Archer Guildsman]";
		mes "Although an Archer has weaker HP, he or she can shoot enemies at a long range,";
		mes "so an Archer is safer in a real battle.";
		next;
		mes "[Archer Guildsman]";
		mes "Although an Archer in Ragnarok has lower HP, he or she has high accuracy and attack rate so that the archer can kill monsters before they get close to an Archer.";
		next;
		mes "[Archer Guildsman]";
		mes "^8C2121An Archer can change jobs to a Hunter.^000000";
		mes "^8C2121Other than Hunter, if you are a man, you can change your job to Bard and if you are a woman, you can change your job to Dancer.^000000";
		close;
	case 3:
		mes "[Archer Guildsman]";
		mes "If you have any questions, feel free to come and ask me.";
		close;
	}
}
