//===== rAthena Script =======================================
//= War of Emperium (Al De Baran) - Neuschwanstein
//===== By: ==================================================
//= L0ne_W0lf
//===== Current Version: =====================================
//= 1.2
//===== Compatible With: =====================================
//= rAthena Project
//===== Description: =========================================
//= NPCs that relate to Al De Baran Guild Castle 1
//===== Additional Comments: =================================
//= 1.0 First Version. No longer uses functions. [L0ne_W0lf]
//= 1.1 Removed dialog from interior flags. [L0ne_W0lf]
//= 1.2 Partially rewrote Script. [Masao]
//============================================================

// Guild Flags (Outside Castle)
//============================================================
-	script	Neuschwanstein#1::OutsideFlagsA1	722,{

	set .@GID, GetCastleData("aldeg_cas01",1);

	if (.@GID == 0) {
		mes "[ Edict of the Divine Rune-Midgarts Kingdom ]";
		mes " ";
		mes "1. Follow the ordinance of The Divine Rune-Midgarts Kingdom, ";
		mes "We declare that";
		mes "there is no formal master of this castle.";
		mes " ";
		mes "2. To the one who can ";
		mes "overcome all trials";
		mes "and destroy the Emperium,";
		mes "the king will endow the one with";
		mes "ownership of this castle.";
		close;
	}
	if (getcharid(2) == .@GID) {
		mes "[ Echoing Voice ]";
		mes "Brave ones...";
		mes "Do you wish to return to your honorable place?";
		next;
		if(select("Return to the guild castle.:Quit.") == 1) {
			close2;
			if (getcharid(2) == GetCastleData("aldeg_cas01",1)) {
				warp "aldeg_cas01",218,170;
				end;
			}
			end;
		}
		close;
	}
	mes "[ Edict of the Divine Rune-Midgarts Kingdom ]";
	mes " ";
	mes "1. Follow the ordinance of The Divine Rune-Midgarts Kingdom, ";
	mes "we approve that this place is in";
	mes "the private prossession of ^ff0000"+GetGuildName(.@GID)+"^000000 Guild.";
	mes " ";
	mes "2. The guild Master of ^ff0000"+GetGuildName(.@GID)+"^000000 Guild is";
	mes "^ff0000"+GetGuildMaster(.@GID)+"^000000";
	mes "If there is anyone who objects to this,";
	mes "prove your strength and honor with a steel blade in your hand.";
	close;

OnRecvCastleA01:
	FlagEmblem GetCastleData("aldeg_cas01",1);
	end;
}

alde_gld,61,87,6	duplicate(OutsideFlagsA1)	Neuschwanstein#1-2	722
alde_gld,61,79,6	duplicate(OutsideFlagsA1)	Neuschwanstein#2	722
alde_gld,45,87,8	duplicate(OutsideFlagsA1)	Neuschwanstein#3	722
alde_gld,51,87,8	duplicate(OutsideFlagsA1)	Neuschwanstein#4	722

// Guild Flags (Inside Castle)
//============================================================
-	script	Neuschwanstein#5::InsideFlagsA1	722,{
	end;

OnRecvCastleA01:
	FlagEmblem GetCastleData("aldeg_cas01",1);
	end;
}

aldeg_cas01,30,248,4	duplicate(InsideFlagsA1)	Neuschwanstein#5-2	722
aldeg_cas01,30,248,4	duplicate(InsideFlagsA1)	Neuschwanstein#6	722
aldeg_cas01,37,248,4	duplicate(InsideFlagsA1)	Neuschwanstein#7	722
aldeg_cas01,37,246,4	duplicate(InsideFlagsA1)	Neuschwanstein#8	722
aldeg_cas01,30,246,4	duplicate(InsideFlagsA1)	Neuschwanstein#9	722
aldeg_cas01,95,80,2	duplicate(InsideFlagsA1)	Neuschwanstein#10	722
aldeg_cas01,95,59,2	duplicate(InsideFlagsA1)	Neuschwanstein#11	722
aldeg_cas01,62,75,2	duplicate(InsideFlagsA1)	Neuschwanstein#12	722
aldeg_cas01,66,75,2	duplicate(InsideFlagsA1)	Neuschwanstein#13	722
aldeg_cas01,70,75,2	duplicate(InsideFlagsA1)	Neuschwanstein#14	722
aldeg_cas01,74,75,2	duplicate(InsideFlagsA1)	Neuschwanstein#15	722
aldeg_cas01,62,64,2	duplicate(InsideFlagsA1)	Neuschwanstein#16	722
aldeg_cas01,66,64,2	duplicate(InsideFlagsA1)	Neuschwanstein#17	722
aldeg_cas01,70,64,2	duplicate(InsideFlagsA1)	Neuschwanstein#18	722
aldeg_cas01,74,64,2	duplicate(InsideFlagsA1)	Neuschwanstein#19	722
aldeg_cas01,74,64,2	duplicate(InsideFlagsA1)	Neuschwanstein#20	722
aldeg_cas01,203,150,4	duplicate(InsideFlagsA1)	Neuschwanstein#21	722
aldeg_cas01,210,150,4	duplicate(InsideFlagsA1)	Neuschwanstein#22	722

// Guild Flag (Town)
//============================================================
aldebaran,152,97,4	duplicate(InsideFlagsA1)	Neuschwanstein#23	722

// Kafra Employee
//============================================================
aldeg_cas01,218,170,0	duplicate(guildkafra)	Kafra Staff#aldeg_cas01	117

// Steward
//============================================================
aldeg_cas01,218,175,0	duplicate(cm)	Alfredo#aldeg_cas01	55

// Treasure Room Exit
//============================================================
aldeg_cas01,123,223,0	script	#lever_A01	111,{
	mes " ";
	mes "There's a small lever. Will you pull it?";
	next;
	if(select("Pull.:Do not.") == 1) {
		close2;
		warp "aldeg_cas01",218,176;
		end;
	}
	close;
}

// Guild Dungeon Switch
//============================================================
aldeg_cas01,211,181,0	duplicate(gdlever)	#aldeg_cas01	111

// Guild Treasure Spawns
//============================================================
aldeg_cas01,118,223,0	duplicate(Gld_Trea_Spawn)	Treasure#aldeg_cas01	-1

// AGIT Manager
//============================================================
aldeg_cas01,216,24,0	duplicate(Gld_Agit_Manager)	Agit#aldeg_cas01	-1

// Guardians
//============================================================
aldeg_cas01,218,175,0	duplicate(Gld_Guard_Template)	Guardian#aldeg_cas01	-1
